Example 3.4 - Thevenin Equivalent of Circuit With "Practical" Op-Amp
*
* NOTE: This is a 2-part problem:
* PART 1: Use .TF command to determine Thevenin equivalent
* PART 2: Use open ckt voltage, current source input method
*
* Assume "practical" op-amp has the values Rin=20E6, Ro=100, A=2E5
*
.OPT NOPAGE NOBIAS
V1 1 0 DC 1 ; output voltage = circuit gain
EAMP 4 0 0 2 2E5 ; practical op-amp gain
R1 1 2 1K
R2 2 3 10K
Ro 3 4 100 ; practical op-amp output resistance
Rin 2 0 20E6 ; practical op-amp input resistance
.TF V(3) V1 ; .TF calculates output/input
.END
Example 3.4, Part 2. Thev Equiv by Open Ckt Volts, Current Source Input
*
* Use .DC "sweep" from 1-volt to 0-volts in a -1-volt step
* Use .STEP command to step current source at output terminals from
* 0 amperes (open-circuit) to 1 ampere. Note that V(3) divided by the
* 1 ampere current is the Thevenin resistance when the independent
* source is reduced to 0, so that V(3) is numerically equal Rthev.
*
* NOTE: Use On-Line Manual or consult Appendix B for rules of .DC sweep
* and .STEP command implementation.
*
.OPT NOPAGE NOBIAS
V1 1 0 DC 1
EAMP 4 0 0 2 2E5
R1 1 2 1K
R2 2 3 10K
Ro 3 4 100
Rin 2 0 20E6
ITEST 0 3 DC 1 ; Current source given value = 1 ampere
.DC V1 1 0 -1 ; DC source goes from 1 to 0, reduces the
; independent source to 0 volts.
.STEP ITEST 0 1 1 ; Current source = 0 is open circuit, the
; voltage V(3) at 1 ampere = Rthev.
.PRINT DC V(1) I(V1) V(3) ; Use V(3)/ITEST = Rthev
.END