Problem 13.9 - Frequency Response of a Fourth-Order Butterworth Filter
*
* Butterworth filter has a "maximally flat" frequency response - that
* is, N-1 derivatives of the magnitude function evaluated at zero (dc)
* frequency are equal to zero, which means that the frequency response
* curve has zero slope, or is "flat," further along the curve toward
* the cutoff frequency than any other filter transfer function.
*
* To compare the fourth-order Butterworth filter of the given circuit
* with a fourth-order RC filter transfer function, run the two-part
* program below. Use the steady-state sinusoidal source and an .AC
* frequency sweep over the range from 10 Hz to 1 Mhz. Assume ideal
* op amps with an open-loop gain A=1E10.
*
* Draw the complete RC filter circuit, consisting of four identical RC
* sections separated by unity-gain "buffer amplifiers." The final load
* on the RC filter is to be the same as on the Butterworth filter.
* Number the nodes on your circuit diagram for the RC filter with
* different numbers than those for the Butterworth so that PSpice does
* not get confused when you graph the node voltages for the two
* filters on the same graph. Enter your RC circuit description in
* the section labeled Part 2, below.
*
* Show that each RC filter section has a critical frequency f=2300 Hz.
* Show that the phase shift for each RC filter section is 45ø at the
* critical frequency, for an overall phase shift of 180ø at 2300 Hz.
* Can you show that the cascade of four identical filters with critical
* frequency of 2300 Hz has the same 1-kHz critical frequency as the
* Butterworth filter?
*
.OPT NOPAGE NOBIAS
V1 1 0 AC 1
R1 1 2 1000
R2 2 4 5000
R3 2 3 830.3
C1 2 0 .5U
C2 3 4 12.2N
E1 4 0 0 3 1E10
R4 4 5 1000
R5 5 7 5000
R6 5 6 587.4
C3 5 0 .25U
C4 6 7 34.5N
E2 7 0 0 6 1E10
RL 7 0 4.7K
.AC DEC 20 10 1E6
.PROBE
.END
*Problem 13.9, Part 2. Frequency Response of Four Identical RC Filter Stages
*
* Enter the RC filter program. Use an ac source of 25 volts (because
* the Butterworth filter has a low-frequency gain of 25). Use all
* DIFFERENT node numbers from the circuit above, so that the voltages
* will be separately identifiable for a PROBE graph. Display the
* transfer function on the same graph as the Butterworth filter above.
*